Başlangıç > Kodlar > VB6’da Avi dosyalarının exe’ye gömülmesi

VB6’da Avi dosyalarının exe’ye gömülmesi


Avi dosyalarının resource file dan oynatılması ile ilgili modül.Avi dosyalarınızı bilgisayarda sabit bir yere kopyalayıp oradan yüklemek yerine resource file a yükleyip oradan çağırarak oynatabilirsiniz.


Option Explicit
'Amaç : Avi dosyalarının resource file dan yüklenerek oynatılması


'TempFile adını alan avi fonksiyonu
Private Declare Function GetTempFileNameAPI Lib "kernel32" Alias "GetTempFileNameA" (ByVal lpszPath As String, ByVal lpPrefixString As String, ByVal wUnique As Long, ByVal lpTempFileName As String) As Long

'TempDirectory nin adını alan avi fonksiyonu
Private Declare Function GetTempPathAPI Lib "kernel32" Alias "GetTempPathA" (ByVal nBufferLength As Long, ByVal lpBuffer As String) As Long

Public Function GetTempPath() As String
'*********************************************************
'Amac   : Temp directory nin adını almak (directory yapısı ile birlikte)
'Giris  : -
'Cikis  : GetTempPath : Temp directory yeri ve adı
'Tarih  : 08.01.2002
'Kisi   : Murat Aras
'*********************************************************

Dim strBuffer As String     'Tampon bölge

'Değişken için 255 karakterlik yer ayrılıyor
strBuffer = Space(255)
'Avi vasıtası ile Temp directory adı alınıyor
GetTempPathAPI Len(strBuffer), strBuffer
'Temp directory adı directory yapısı ile birlikte fonksiyona değer olarak atanıyor
GetTempPath = Left(strBuffer, InStr(strBuffer, Chr(0)) - 1)

End Function

Public Function GetTempFileName(strPrefix As String) As String
'*********************************************************'Amac   : Dosya adını almak
'Giris  : strPrefix : Dosya öneki
'Cikis  : GetTempFile : Dosya adı
'Tarih  : 08.01.2002
'Kisi   : Murat Aras
'*********************************************************
Dim strBuffer As String     'Tampon bölge

'Değişken için 255 karakterlik yer ayrılıyor
strBuffer = Space(255)
'Avi vasıtası ile dosya adı alınıyor
GetTempFileNameAPI GetTempPath, strPrefix, 0, strBuffer
'Dosya adı fonksiyona değer olarak atanıyor
GetTempFileName = Left(strBuffer, InStr(strBuffer, Chr(0)) - 1)

End Function

Public Sub LoadVideo(ctrlAnimation As Animation, lResourceID As Long)
'*********************************************************'Amac   : Avi dosyasını temp dosya olarak yaratıp animation control e yüklemek
'Giris  : ctrlAnimation : Animation control adı
'         lResourceID : Avi dosyasının resource file kodu
'Cikis  : -
'Tarih  : 08.01.2002
'Kisi   : Murat Aras
'*********************************************************
Dim arrByteData() As Byte       'Avi dosyasının byte byte aktarılacağı dizi
Dim lFileNumber As Long         'Dosya numarası
Dim strTempFile As String       'Temp file adı
'Avi file data değişkenine atanıyor
arrByteData = LoadResData(lResourceID, "CUSTOM")
'Boşta bir dosya numarası alınıyor
lFileNumber = FreeFile
'Avi dosyası için temp directory altında isim alınıyor
strTempFile = GetTempFileName("ANI")
'Temp dosya açılıyor
Open strTempFile For Binary Access Write As lFileNumber
'Avi file dosyaya yükleniyor
Put lFileNumber, , arrByteData
'Dosya kapatılıyor
Close lFileNumber
'Oluşturulan dosya avi file olarak animation control e yükleniyor
ctrlAnimation.Open strTempFile

End Sub

Public Sub UnloadVideo(ctrlAnimation As Animation)
'*********************************************************'Amac   : Avi dosyasını unload etmek
'Giris  : ctrlAnimation : Animation control adı
'Cikis  : -
'Tarih  : 08.01.2002
'Kisi   : Murat Aras
'*********************************************************
ctrlAnimation.Close

End Sub

Reklamlar
  1. Henüz yorum yapılmamış.
  1. No trackbacks yet.

Bir Cevap Yazın

Aşağıya bilgilerinizi girin veya oturum açmak için bir simgeye tıklayın:

WordPress.com Logosu

WordPress.com hesabınızı kullanarak yorum yapıyorsunuz. Çıkış  Yap / Değiştir )

Twitter resmi

Twitter hesabınızı kullanarak yorum yapıyorsunuz. Çıkış  Yap / Değiştir )

Facebook fotoğrafı

Facebook hesabınızı kullanarak yorum yapıyorsunuz. Çıkış  Yap / Değiştir )

Google+ fotoğrafı

Google+ hesabınızı kullanarak yorum yapıyorsunuz. Çıkış  Yap / Değiştir )

Connecting to %s

%d blogcu bunu beğendi: